中文字幕二区_国产精品免费在线观看_黄色网站观看_人人草人人澡_日本真实娇小xxxx

之前根據(jù)教程，已經(jīng)了解了Sandy的基本知識，可以說Sandy已經(jīng)對我們敞開了大門，我們可以在Flash3D的世界里自由飛翔了。
接下來，要更加深入的對Sandy進行了解了，正式進入高級教程的部分。

這個章節(jié)是介紹關(guān)于Sandy 3D的精確顯示。

這次使用的是Plane3D這個基元，這個形狀是平面體，我把它理解為3D場景里的一張紙片。

public function Plane3D(p_sName:String = null, p_nHeight:Number = 100, p_nWidth:Number = 100, p_nQualityH:uint = 1, p_nQualityV:uint = 1, p_sType:String, p_sMode:String = null)

他的參數(shù)比較多：

p_sName:String (default = null) — 給實例命名
p_nHeight:Number (default = 100) — 平面體的高度
p_nWidth:Number (default = 100) — 平面體的寬度
p_nQualityH:uint (default = 1) — 橫向的段數(shù)
p_nQualityV:uint (default = 1) — 縱向的段數(shù)
p_sType:String — 位平面體定向, （ XY_ALIGNED ( default ), YZ_ALIGNED or ZX_ALIGNED ）
p_sMode:String (default = null) — 模式（tri 模式有3個頂點、quad 模式有4個頂點）

代碼：

package
{
    import flash.display.Sprite;
    import flash.events.*;
    import flash.ui.*;
    import sandy.core.Scene3D;
    import sandy.core.data.*;
    import sandy.core.scenegraph.*;
    import sandy.materials.*;
    import sandy.materials.attributes.*;
    import sandy.primitive.*;
   
    /**
     * ...
     * @author ever5u
     */
    public class fuxi extends Sprite
    {
        private var scene:Scene3D;
        private var camera:Camera3D;
        private var tg:TransformGroup;
       
        public function fuxi() {
            //先創(chuàng)建攝像機
            camera = new Camera3D( 300, 300 );
            camera.z = -400;
            camera.lookAt(0,0,0);
            //創(chuàng)建 Group
            var root:Group = createScene();
            //創(chuàng)建場景
            scene = new Scene3D( "scene", canvas, camera, root );
            scene.rectClipping = true;
            addEventListener( Event.ENTER_FRAME, enterFrameHandler );
            stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressedHandler);
        }
        private function createScene():Group {
            var g:Group = new Group();
            tg = new TransformGroup('myGroup');
            //創(chuàng)建幾個平面體，并定義坐標使其組合成為一個形狀
            var right:Shape3D = new Plane3D('right', 150, 100, 10, 10, Plane3D.YZ_ALIGNED,'quad');
                right.moveLateraly(100);
                right.moveForward(50)
            var left:Shape3D = new Plane3D('left', 150, 100, 10, 10, Plane3D.YZ_ALIGNED,'quad');
                left.moveLateraly(-100);
                left.moveForward(50)
            var back:Shape3D = new Plane3D('back', 100, 250, 10, 10, Plane3D.XY_ALIGNED,'quad');
                back.moveForward(100);
            var bottom:Shape3D = new Plane3D('bottom', 150, 250, 10, 10, Plane3D.ZX_ALIGNED,'quad');
                bottom.moveForward(50);
                bottom.moveUpwards( -50);
            //著色設(shè)置
            var materialAttr:MaterialAttributes = new MaterialAttributes(
                new LineAttributes( 0.5, 0x2111BB, 0.4 ),
                new LightAttributes( true, 0.1)
                );
            var material01:Material = new ColorMaterial( 0xFFCC33, 1, materialAttr );
            material01.lightingEnable = false;
            var material02:Material = new ColorMaterial( 0xFEA792, 1, materialAttr );
            material02.lightingEnable = false;
            var app01:Appearance = new Appearance( material01 );
            var app02:Appearance = new Appearance( material02 );
            //應(yīng)用著色
            right.enableBackFaceCulling = false;
            right.appearance = app01;
            left.enableBackFaceCulling = false;
            left.appearance = app01;
            back.enableBackFaceCulling = false;
            back.appearance = app02;
            bottom.enableBackFaceCulling = true;
            bottom.appearance = app02;
            //是否獨立渲染
            right.useSingleContainer = false;
            left.useSingleContainer = false;
            back.useSingleContainer = false;
            bottom.useSingleContainer = false;
            //組合到組
            tg.addChild(right);
            tg.addChild(left);
            tg.addChild(back);
            tg.addChild(bottom);
            g.addChild(tg);
            return g;
        }
        private function enterFrameHandler( event : Event ) : void {
            scene.render();
        }
        private function keyPressedHandler(event:KeyboardEvent):void {
            switch(event.keyCode) {
                case Keyboard.UP:
                    tg.tilt +=2;
                    break;
                case Keyboard.DOWN:
                    tg.tilt -=2;
                    break;
                case Keyboard.RIGHT:
                    tg.pan +=2;
                    break;
                case Keyboard.LEFT:
                    tg.pan -=2;
                    break;
            }
        }   
    }   
}

效果：

當(dāng) useSingleContainer = true 時的效果，用鍵盤旋轉(zhuǎn)一下就能看到其中的不同之處。

出處：藍色理想
責(zé)任編輯：bluehearts

上一頁 Flash3D學(xué)習(xí)——Sandy學(xué)習(xí)筆記 [10] 下一頁 Flash3D學(xué)習(xí)——Sandy學(xué)習(xí)筆記 [12]

◎進入論壇RIA設(shè)計與應(yīng)用版塊參加討論